Εδώ ψάχνεις...

[How to]: Πως βρίσκουμε τον κωδικό εγκατάστασης των Windows

Τρίτη, 29 Νοεμβρίου 2016


Πολλοί είμαστε ξεχασιάρηδες και δεν θυμόμαστε που έχουμε αποθηκεύσει το κλειδί εγκατάστασης των Windows. Βέβαια, θα μου πείτε ότι πέρασαν χρόνια από τότε και που μυαλό γιαυτό. Εμείς σας έχουμε την λύση χωρίς την εγκατάσταση κάποιου προγράμματος!

Παλιότερα σας είχαμε παρουσιάσει ένα παρόμοιο πρόγραμμα, αλλά κάποιοι χρήστες παραπονέθηκαν για λανθασμένο κωδικό σε ορισμένες εκδόσεις windows. Σημειωτέον, ότι λειτουργεί άψογα με Windows 7/8.1 αλλά και 10!

Λοιπόν ξεκινάμε:

Ανοίξτε ένα Notepad (επεξεργαστή κειμένου) ή το σημειωματάριο των windows και επικολλήστε επακριβώς τον παρακάτω κώδικα:
Option Explicit

Dim objshell,path,DigitalID, Result
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey
'Show messbox if save to a file
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
   Save ProductData
End If



'Convert binary to chars
Function ConvertToKey(Key)
    Const KeyOffset = 52
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
    'Check if OS is Windows 8
    isWin8 = (Key(66) \ 6) And 1
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
    i = 24
    Maps = "BCDFGHJKMPQRTVWXY2346789"
    Do
           Current= 0
        j = 14
        Do
           Current = Current* 256
           Current = Key(j + KeyOffset) + Current
           Key(j + KeyOffset) = (Current \ 24)
           Current=Current Mod 24
            j = j -1
        Loop While j >= 0
        i = i -1
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
        Last = Current
    Loop While i >= 0
    keypart1 = Mid(KeyOutput, 2, Last)
    insert = "N"
    KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
    If Last = 0 Then KeyOutput = insert & KeyOutput
    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
  
   
End Function
'Save data to a file
Function Save(Data)
    Dim fso, fName, txt,objshell,UserName
    Set objshell = CreateObject("wscript.shell")
    'Get current user name
    UserName = objshell.ExpandEnvironmentStrings("%UserName%")
    'Create a text file on desktop
    fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set txt = fso.CreateTextFile(fName)
    txt.Writeline Data
    txt.Close


End Function

Ανοίγουμε το σημειωματάριο και επικολλούμε τον κώδικα
Αφού το επικολλήσατε, σώστε το αρχείο με κατάληξη .vbs πχ: dwrean.vbs. Εν συνεχεία, κάντε διπλό κλικ στο αρχείο .vbs που μόλις αποθηκεύσατε και Voila! Το κλειδί εγκατάστασης των Windows έτοιμο!
σώσε το αρχείο με κατάληξη .vbs

με διπλό κλικ, εμφανίζεται ο κωδικός
Αν θέλετε να αποφύγετε την διαδικασία, μπορείτε να πάρετε έτοιμο το αρχείο .vbs του dwrean.net που ετοιμάσαμε για εσάς! Κλικ εδώ για το αρχείο

Συντάκτης του άρθρου: Κυριάκος Οικονομίδης


 
 
 

Social Media

Ακολουθήστε μας στα Σόσιαλ Μίντια:

Paypal Donate

Αν θέλεις να συνεισφέρεις στο έργο μας, μπορείς να κάνεις μια δωρεά μέσω Paypal:

Έτσι μας είπαν να σας πούμε...

Για να είσαι σένιος και ντόμπρος όπως είμαστε εμείς, κάτσε και βλεφάρισε το παρακάτω κειμενάκι:

Φιλικοί σύνδεσμοι

Μας αγαπούν και τους αγαπάμε:

Χρήσιμα | Ο γιατρός του Android | Ειδησεις | xariseto.gr